|
|
|
| Convertire documenti Word in HTML |
utilizzeremo l'oggetto Word.Application per convertire un documento in formato Word in un file HTML.
Lo script e` diviso in due parti, la funzione vera e prorpia e la chiamata alla stessa.
<%
Function WordToHTML(strWordDoc, strHTMLDoc)
On Error Resume Next
'Istanziamo l'oggetto Word.Application, lo rendiamo invisibile e apriamo il file
Dim objWord
Set objWord = Server.CreateObject("Word.Application")
objWord.Visible = False
'path completo
objWord.Documents.Open(strWordDoc)
'Se ci sono errori ne visualizziamo la descrizione
If Err.Number <> 0 Then
WordToHTML = Err.Description
Else
'Impostiamo le proprieta` della conversione
FileFormat=106
LockComments=True
Password=""
AddToRecentFiles=False
WritePassword=""
ReadOnlyRecommended=False
EmbedTrueTypeFonts=False
SaveNativePictureFormat=True
SaveFormsData=False
SaveAsAOCELetter=False
'Effettuiamo la conversione
objWord.ActiveDocument.SaveAs strHTMLDoc, FileFormat, LockComments, _
Password, AddToRecentFiles, WritePassword, ReadOnlyRecommended, _
EmbedTrueTypeFonts ,SaveNativePictureFormat, SaveFormsData, SaveAsAOCELetter
'Se ci sono errori ne visualizziamo la descrizione
If Err.Number <> 0 Then
Response.Write Err.Description & "<br>"
WordToHTML = Err.Description
Else
WordToHTML = "Conversione eseguita con successo"
'Chiudiamo l'oggetto e liberiamo la memoria
objWord.ActiveDocument.Close
objWord.Quit
Set objWord = Nothing
'Facciamo l'ultimo controllo degli errori
If Err.Number <> 0 Then
WordToHTML = Err.Description
Else
WordToHTML = "Conversione eseguita con successo"
End If
End If
End If
End Function
Conversione = WordToHTML(Server.MapPath("test.doc"), Server.MapPath("test.htm"))
Response.Write "<br><br>" & Conversione & "<br><br>"
%>
|
|
|
|
Stampa 
